NewDeal Hot Tip 1104

Telecommunications

NewComm Scripts for Beginners

A script is a file that gives instructions over your modem. Many people use scripts to enter an ID or user number and a password when calling a local or commercial BBS.

Two script files are included with NewDeal for use with NewComm: GENIE.MAC for GEnie and COMPU.MAC for CompuServe. These are sample files and may need editing before they will work properly with NewComm and your particular configuration. Both of these files are set for COM1. If your modem is not connected to COM1, then this will have to be changed (the scripts won't work and may even change your settings).

Other examples of things you may need to change in the script files are BAUD rate, parity, data bits, and stop bits.

The most common settings for many BBS's are: 2400, 8,n,1 (this means 2400 baud, 8 data bits, no parity, one stop bit). For the GEnie script, you probably want 2400 7,e,1.

If you've had some experience using scripts, you may also want to include your id/password and any necessary logon information.

The easiest way to edit the script file is to use Text File Editor. Both COMPU.MAC and GENIE.MAC are located in \USERDATA\COMMACRO.

When you've finished editing, save the file. If you used a word processor or other text editor, be sure to save as a text file.

If you don't want to overwrite your original script, give it a different name. As long as you use the extension .MAC, NewComm will see it as a script file. (HINT: you can create any number of scripts, just call them NAME.MAC where "name" is the name of the script).

Sample NewComm script for BBS log on

;
;SAMPLE. logon file
;
; $Id: SAMPLE.MAC,v 1.3 90/12/07 11:45:39 DAVE G. Exp $
;
PRINT  "THIS IS A SAMPLE SCRIPT FILE",CR
PRINT  "FOR SIGN-ON TO LOCAL BULLETIN", CR
PRINT  "BOARDS, SUCH AS WILDCAT AND RBBS",CR
PRINT  "PORT, COMM, TERM, DIAL, CONNECTED TO,",CR
PRINT  "FIRST AND LAST NAME, AND PASSWORD",CR
PRINT  "FIELDS MUST BE EDITED"
PRINT  "FOR YOUR PREFERENCES"
PAUSE
PORT  2
:comm
COMM  2400-8-N-1-FULL
TERM  TTY
; clear the script display
CLEAR
:retry
PAUSE
PRINT  "DIALING" , CR
DIAL  "555-1111"
MATCH  "BUSY"  GOTO  retry
MATCH  "NO"  GOTO  retry
MATCH  "CONNECT 2400"  GOTO  connect
PROMPT  4800
PRINT  "TIMEOUT ON DIAL",CR
GOTO  done
:connect
PRINT  "Connected to the BBS NAME", CR
PAUSE
MATCH  "What is your FIRST Name?" GOTO first
PROMPT  600
PRINT  "TIMEOUT ON FIRST NAME",CR
GOTO  done
:first
PRINT  "Sending FIRST NAME", CR
PAUSE
SEND  "FIRST NAME",CR
MATCH  "What is your LAST Name?" GOTO  last
PROMPT  600
PRINT  "TIMEOUT ON LAST NAME",CR
GOTO  done
:last
PRINT  "Sending LAST NAME", CR
PAUSE
SEND  "LAST NAME",CR
MATCH  "Enter Password (dots will echo)?"GOTO pword
PROMPT  600
PRINT  "TIMEOUT ON PASSWORD",CR
GOTO  done
:pword
PRINT  "Sending password", CR
PAUSE
SEND  "PASSWORD",CR
:done
BELL
PRINT  "  * * *DONE* * *",CR
PRINT  "PLEASE CLICK ON CLOSE",CR
END
:ABORT
PRINT  "HANGING UP",CR
SEND  "+"
MATCH  "OK" GOTO done
MATCH  "NO CARRIER" GOTO done
PROMPT  300
PRINT  "Couldn't disconnect the modem",CR
GOTO  end
; Hangup the connection
:dohup
SEND  "ATH0",CR
MATCH  "OK"  GOTO  hangup
PROMPT  900
PRINT  "TIMEOUT ON hangup",CR
GOTO  end
:hangup
PRINT  "HUNG UP",CR
:end
BELL
END